技術情報
メソッド
Addメソッド BuildPathメソッド Closeメソッド
Copyメソッド CopyFileメソッド CopyFolderメソッド
CreateFolderメソッド CreateTextFileメソッド Deleteメソッド
DeleteFileメソッド DeleteFolderメソッド DriveExistsメソッド
FileExistsメソッド FolderExistsメソッド GetAbsolutePathNameメソッド
GetBaseNameメソッド GetDriveメソッド GetDriveNameメソッド
GetExtensionNameメソッド GetFileメソッド GetFileNameメソッド
GetFileVersionメソッド GetFolderメソッド GetParentFolderNameメソッド
GetSpecialFolderメソッド GetTempNameメソッド Moveメソッド
MoveFileメソッド MoveFolderメソッド OpenAsTextStreamメソッド
OpenTextFileメソッド Readメソッド ReadAllメソッド
ReadLineメソッド Skipメソッド SkipLineメソッド
Writeメソッド WriteBlankLinesメソッド WriteLineメソッド


Addメソッド
新しいサブフォルダを追加します。
書式 "Foldersコレクション".Add(引数1)
■ 引数1(必須)
追加するサブフォルダ名を指定します。

[戻り値]
追加したサブフォルダのフルパス

[備考]
新しいサブフォルダを追加したい親フォルダのFolderオブジェクトを取得し、そのサブフォルダに追加するようにします。
既に同じサブフォルダが存在する場合は、エラーとなります。

(例)
'「D:\Temp」に「Sample」サブフォルダを作成します。
Dim oFSO, oFolder, StrPath
Set oFSO = CreateObject("Scripting.FileSystemObject")
StrPath = "D:\Temp"
Set oFolder = oFSO.GetFolder(StrPath)
oFolder.SubFolders.Add("Sample")
Set oFolder = Nothing
Set oFSO = Nothing


BuildPathメソッド
既存の末尾に別の名前を追加したパス文字列を返します。
書式 "FileSystemObjectオブジェクト".BuildPath(引数1,引数2)
■ 引数1(必須)
既存のパスを指定します。
■ 引数2(必須)
追加する別の名前を指定します。

[戻り値]
引数1のパスと引数2の名前を「\」でつないだパス文字列

[備考]
引数1の既存パスも引数2の名前も存在しないものを指定してもエラーにはなりません。

(例)
'「D:\Temp」に「Sample」を結合したパス文字列を作成します。
'「D:\Temp\Sample」と表示されます。
Dim oFSO, StrPath
Set oFSO = CreateObject("Scripting.FileSystemObject")
StrPath = "D:\Temp"
MsgBox oFSO.BuildPath(StrPath, "Sample")
Set oFSO = Nothing


Closeメソッド
開いているTextStreamオブジェクトを閉じます。
書式 "TextStreamオブジェクト".Close

[戻り値]

(例)
'テキストファイルに書き込みます。
Dim oFSO, oFile, StrPath
Set oFSO = CreateObject("Scripting.FileSystemObject")
StrPath = "D:\Temp"
Set oFile = oFSO.CreateTextFile(StrPath & "\test.txt", True)
oFile.WriteLine("テストです")
oFile.Close
Set oFile = Nothing
Set oFSO = Nothing


Copyメソッド
ファイルまたはフォルダをコピーします。
書式 "Fileオブジェクト".Copy(引数1,引数2)
"Folderオブジェクト".Copy(引数1,引数2)
■ 引数1(必須)
コピー先のパスを指定します。
■ 引数2
上書きする場合は True、上書きしない場合は False を指定します。
未指定の場合は、True となります。

[戻り値]

[備考]
Fileオブジェクトで指定されたファイルまたはFolderオブジェクトで指定されたフォルダを引数1のコピー先にコピーします。

(例)
'「D:\Temp」にあるファイルをコピーします。
Dim oFSO, oFile
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFile = oFSO.GetFile("D:\Temp\File1.txt")
oFile.Copy "D:\Temp\File2.txt", True
Set oFile = Nothing
Set oFSO = Nothing


CopyFileメソッド
ファイルをコピーします。
書式 "FileSystemObjectオブジェクト".CopyFile(引数1,引数2,引数3)
■ 引数1(必須)
コピー元のファイルパスを指定します。
ワイルドカードを使用することができます。
■ 引数2(必須)
コピー先のパスをファイル名まで含めて指定するか、コピー先のフォルダパスのいずれかを指定します。
なお、フォルダパスを指定する場合は、その場合は最後に「\」を付けてください。
また、ワイルドカードは使用できません。
■ 引数3
上書きする場合は True、上書きしない場合は False を指定します。
未指定の場合は、True となります。

[戻り値]

(例)
'「D:\Temp」にあるファイルをコピーします。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
'コピー先にフォルダパスを指定した場合です。
oFSO.CopyFile "D:\Temp\File1.txt","D:\Data\", True
'コピー先にファイル名も含めたパスを指定した場合です。
oFSO.CopyFile "D:\Temp\File1.txt","D:\Temp\File2.txt", True
Set oFSO = Nothing


CopyFolderメソッド
フォルダをコピーします。
書式 "FileSystemObjectオブジェクト".CopyFolder(引数1,引数2,引数3)
■ 引数1(必須)
コピー元のフォルダパスを指定します。
ワイルドカードを使用することができます。
■ 引数2(必須)
コピー先のパスをフォルダ名まで含めて指定するか、コピー先の親フォルダパスのいずれかを指定します。
なお、親フォルダパスを指定する場合は、その場合は最後に「\」を付けてください。
また、ワイルドカードは使用できません。
■ 引数3
上書きする場合は True、上書きしない場合は False を指定します。
未指定の場合は、True となります。

[戻り値]

(例)
'「D:\Temp」にあるフォルダをコピーします。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
'コピー先に親フォルダパスを指定した場合です。
oFSO.CopyFolder "D:\Temp\Folder1","D:\Data\", True
'コピー先にフォルダ名も含めたパスを指定した場合です。
oFSO.CopyFolder "D:\Temp\Folder1","D:\Temp\Folder2", True
Set oFSO = Nothing


CreateFolderメソッド
フォルダを作成します。
書式 "FileSystemObjectオブジェクト".CreateFolder(引数1)
■ 引数1(必須)
作成するフォルダのパスを指定します。

[戻り値]
Folderオブジェクト

[備考]
指定したフォルダが既に存在している場合は、エラーとなります。

(例)
'「D:\Temp」に「Sample」サブフォルダを作成します。
Dim oFSO, oFolder
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFolder = oFSO.CreateFolder("D:\Temp\Sample")
Set oFSO = Nothing


CreateTextFileメソッド
テキストファイルを作成します。
書式 "FileSystemObjectオブジェクト".CreateTextFile(引数1,引数2,引数3)
■ 引数1(必須)
作成するテキストファイルのパスを指定します。
■ 引数2
上書きする場合は True、上書きしない場合は False を指定します。
未指定の場合は、True となります。
■ 引数3
文字コードを表すブール値を指定します。
Unicodeの場合は True、ASCIIの場合は False を指定します。
未指定の場合は、False となります。

[戻り値]
TextStreamオブジェクト

(例)
'「D:\Temp」にテキストファイルを作成します。
Dim oFSO, oFile
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFile = oFSO.CreateTextFile("D:\Temp\File.txt", True)
oFile.WriteLine("テストです")
oFile.Close
Set oFile = Nothing
Set oFSO = Nothing


Deleteメソッド
ファイルまたはフォルダを削除します。
書式 "Fileオブジェクト".Delete(引数1)
"Folderオブジェクト".Delete(引数1)
■ 引数1
読み取り専用のファイルやフォルダも削除する場合は True を指定します。
未指定の場合は、False となります。

[戻り値]

[備考]
Fileオブジェクトで指定されたファイルまたはFolderオブジェクトで指定されたフォルダを削除します。

(例)
'「D:\Temp\Sample」フォルダを削除します。
Dim oFSO, oFolder
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFolder = oFSO.GetFolder("D:\Temp\Sample")
oFolder.Delete
Set oFolder = Nothing
Set oFSO = Nothing


DeleteFileメソッド
ファイルを削除します。
書式 "FileSystemObjectオブジェクト".Delete(引数1,引数2)
■ 引数1(必須)
削除対象のファイルのパスを指定します。
ワイルドカードを使用することができます。
■ 引数2
読み取り専用のファイルも削除する場合には True を指定します。
未指定の場合は、False となります。

[戻り値]

(例)
'「D:\Temp\File1.txt」を削除します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
oFSO.DeleteFile("D:\Temp\File1.txt", True)
Set oFSO = Nothing


DeleteFolderメソッド
フォルダを削除します。
書式 "FileSystemObjectオブジェクト".DeleteFolder(引数1,引数2)
■ 引数1(必須)
削除対象のフォルダのパスを指定します。
ワイルドカードを使用することができます。
■ 引数2
読み取り専用のフォルダも削除する場合には True を指定します。
未指定の場合は、False となります。

[戻り値]

(例)
'「D:\Temp\Sample」を削除します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
oFSO.DeleteFolder("D:\Temp\Sample", True)
Set oFSO = Nothing


DriveExistsメソッド
ドライブの有無を確認します。
書式 "FileSystemObjectオブジェクト".DriveExists(引数1)
■ 引数1(必須)
ドライブ名を指定します。

[戻り値]
True 指定したドライブは存在します。
False 指定したドライブは存在しません。

[備考]
MOなどのリムーバブルメディアドライブの場合は、メディアがセットされていなくてもドライブがあれば、True を返しますので、注意してください。

(例)
'「D:」ドライブの有無を確認します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
If oFSO.DriveExists("D:") = True Then
  WScript.Echo "Dドライブはあります"
Else
  WScript.Echo "Dドライブはありません"
End If
Set oFSO = Nothing


FileExistsメソッド
ファイルの有無を確認します。
書式 "FileSystemObjectオブジェクト".FileExists(引数1)
■ 引数1(必須)
ファイルのパスを指定します。

[戻り値]
True 指定したファイルは存在します。
False 指定したファイルは存在しません。

(例)
'「D:\Temp\File1.txt」ファイルの有無を確認します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
If oFSO.FileExists("D:\Temp\File1.txt") = True Then
  WScript.Echo "ファイルはあります"
Else
  WScript.Echo "ファイルはありません"
End If
Set oFSO = Nothing


FolderExistsメソッド
フォルダの有無を確認します。
書式 "FileSystemObjectオブジェクト".FolderExists(引数1)
■ 引数1(必須)
フォルダのパスを指定します。

[戻り値]
True 指定したフォルダは存在します。
False 指定したフォルダは存在しません。

(例)
'「D:\Temp」フォルダの有無を確認します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
If oFSO.FolderExists("D:\Temp") = True Then
  WScript.Echo "フォルダはあります"
Else
  WScript.Echo "フォルダはありません"
End If
Set oFSO = Nothing


GetAbsolutePathNameメソッド
相対パスを絶対パスに変換した結果を返します。
書式 "FileSystemObjectオブジェクト".GetAbsolutePathName(引数1)
■ 引数1(必須)
ファイルやフォルダの相対パスを指定します。

[戻り値]
絶対パス

[備考]
スクリプトをエクスプローラからダブルクリックして実行した場合、そのスクリプトファイルが置かれているフォルダのパスが基準ディレクトリとなります。
コマンドプロンプトから実行した場合は、コマンドプロンプトのカレントディレクトリが基準ディレクトリとなります。
基準ディレクトリから見て、引数1で指定された相対パスの絶対パスを返します。
引数1で指定した相対パスが実際に存在しなくても、エラーにはなりません。

(例)
'「Sample」フォルダの絶対パスを表示します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
WScript.Echo oFSO.GetAbsolutePathName("Sample")
Set oFSO = Nothing


GetBaseNameメソッド
パスに含まれる末端のファイル名やフォルダ名を返します。
書式 "FileSystemObjectオブジェクト".GetBaseName(引数1)
■ 引数1(必須)
ファイルまたはフォルダのパスを指定します。

[戻り値]
ファイル名またはフォルダ名

[備考]
引数1で指定したパスが実際に存在しなくてもエラーにはなりません。
引数1にファイルを指定した場合は拡張子と「.」を除いたファイル名を返します。

(例)
'「D:\Temp\Sample」のフォルダ名のみを取得します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
WScript.Echo oFSO.GetBaseName("D:\Temp\Sample")
Set oFSO = Nothing


GetDriveメソッド
指定されたパスに含まれるDriveオブジェクトを返します。
書式 "FileSystemObjectオブジェクト".GetDrive(引数1)
■ 引数1(必須)
ドライブ名を表す文字列を指定します。
例えば、Dドライブの場合は「D」「D:」「D:\」、共有フォルダの場合は「\\マシン名\共有名」を指定します。

[戻り値]
Driveオブジェクト

(例)
'「D:」のDriveオブジェクトを取得します。
Dim oFSO, oDrive
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oDrive = oFSO.GetDrive("D:")
WScript.Echo oDrive.Path
Set oDrive = Nothing
Set oFSO = Nothing


GetDriveNameメソッド
指定したパスのドライブ名を返します。
書式 "FileSystemObjectオブジェクト".GetDriveName(引数1)
■ 引数1(必須)
ファイルまたはフォルダのパスを指定します。

[戻り値]
ドライブ文字 + :

[備考]
引数1で指定されたパスが実際に存在しなくてもエラーにはなりません。

(例)
'「D:\Temp」ドライブ名を表示します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
WScript.Echo oFSO.GetDriveName("D:\Temp")
Set oFSO = Nothing


GetExtensionNameメソッド
指定したファイルの拡張子を返します。
書式 "FileSystemObjectオブジェクト".GetExtensionName(引数1)
■ 引数1(必須)
ファイルのパスを指定します。

[戻り値]
ファイルの拡張子

[備考]
引数1にフォルダパスを指定した場合は空文字列("")を返します。
戻り値の拡張子に「.」は含まれません。

(例)
'「D:\Temp\File.txt」の拡張子を表示します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
WScript.Echo oFSO.GetExtensionName("D:\Temp\File.txt")
Set oFSO = Nothing


GetFileメソッド
指定したファイルのFileオブジェクトを返します。
書式 "FileSystemObjectオブジェクト".GetFile(引数1)
■ 引数1(必須)
ファイルパスを指定します。

[戻り値]
Fileオブジェクト

(例)
'「D:\Temp\File.txt」のFileオブジェクトを取得します。
Dim oFSO, oFile
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFile = oFSO.GetFile("D:\Temp\File.txt")
WScript.Echo oFile.DateCreated
Set oFile = Nothing
Set oFSO = Nothing


GetFileNameメソッド
パスに含まれる末端のファイル名(拡張子含む)を返します。
書式 "FileSystemObjectオブジェクト".GetFileName(引数1)
■ 引数1(必須)
ファイルパスを指定します。

[戻り値]
ファイル名

[備考]
引数1で指定したファイルが存在しなくてもエラーにはなりません。
戻り値のファイル名には拡張子が含まれます。

(例)
'「D:\Temp\File.txt」のファイル名を表示します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
WScript.Echo oFSO.GetFileName("D:\Temp\File.txt")
Set oFSO = Nothing


GetFileVersionメソッド
ファイルのバージョン番号を返します。
書式 "FileSystemObjectオブジェクト".GetFileVersion(引数1)
■ 引数1(必須)
ファイルパスを指定します。

[戻り値]
バージョン番号

[備考]
引数1で指定したファイルにバージョン番号が設定されていない場合は空文字列("")を返します。

(例)
'「D:\Temp\myApp.exe」のバージョン番号を表示します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
WScript.Echo oFSO.GetFileVersion("D:\Temp\myApp.exe")
Set oFSO = Nothing


GetFolderメソッド
指定したフォルダのFolderオブジェクトを返します。
書式 "FileSystemObjectオブジェクト".GetFolder(引数1)
■ 引数1(必須)
フォルダパスを指定します。

[戻り値]
Folderオブジェクト

(例)
'「D:\Temp\Sample」のFolderオブジェクトを取得します。
Dim oFSO, oFolder
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFolder = oFSO.GetFolder("D:\Temp\Sample")
WScript.Echo oFolder.DateCreated
Set oFolder = Nothing
Set oFSO = Nothing


GetParentFolderNameメソッド
指定したファイルまたはフォルダの親フォルダのパスを返します。
書式 "FileSystemObjectオブジェクト".GetParentFolderName(引数1)
■ 引数1(必須)
ファイルパスまたはフォルダパスを指定します。

[戻り値]
親フォルダのパス

[備考]
引数1で指定したファイルやフォルダが存在しなくてもエラーになりません。

(例)
'「D:\Temp\Sample」の親フォルダを表示します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
WScript.Echo oFSO.GetParentFolderName("D:\Temp\Sample")
Set oFSO = Nothing


GetSpecialFolderメソッド
指定した特殊フォルダのFolderオブジェクトを返します。
書式 "FileSystemObjectオブジェクト".GetSpecialFolder(引数1)
■ 引数1(必須)
特殊フォルダを表す定数または値を以下から指定します。
定数 説明
WindowsFolder 0 Windowsフォルダ
SystemFolder 1 Systemフォルダ
TemporaryFolder 2 Tempフォルダ

[戻り値]
Folderオブジェクト

(例)
'WindowsフォルダのFolderオブジェクトを取得します。
Dim oFSO, oFolder
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFolder = oFSO.GetSpecialFolder(WindowsFolder)
WScript.Echo oFolder.DateCreated
Set oFolder = Nothing
Set oFSO = Nothing


GetTempNameメソッド
一時ファイル名をランダムに生成して返します。
書式 "FileSystemObjectオブジェクト".GetTempName

[戻り値]
ランダムなファイル名

[備考]
ランダムなファイル名には拡張子「.tmp」がつきます。
また、ファイル名を返すだけで実際にファイルは作成されません。

(例)
'一時ファイル名を表示します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
WScript.Echo oFSO.GetTempName
Set oFSO = Nothing


Moveメソッド
ファイルまたはフォルダを移動します。
書式 "Fileオブジェクト".Move(引数1)
"Folderオブジェクト".Move(引数1)
■ 引数1(必須)
移動先のパスを指定します。

[戻り値]

[備考]
引数1に移動先フォルダのパスを指定する場合には、パスの最後に「\」を付けてください。
移動に成功すると、移動元のファイルやフォルダは削除されます。
また、移動と同時に元ファイル名や元フォルダ名を変更する事もできます。

(例)
'「D:\Temp」にあるファイルとサブフォルダをコピーします。
Dim oFSO, oFolder, oFile
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFolder = oFSO.GetFolder("D:\Temp")
Set oFile = oFSO.GetFile("D:\Temp\File1.txt")
'移動先のフォルダパスを指定する場合
oFolder.Move("D:\Data\")
'移動先のファイル名まで含めて指定する場合
'(移動と同時にファイル名を変更)
oFile.Move("D:\Data\File2.txt")
Set oFile = Nothing
Set oFolder = Nothing
Set oFSO = Nothing


MoveFileメソッド
ファイルを移動します。
書式 "FileSystemObjectオブジェクト".MoveFile(引数1,引数2)
■ 引数1(必須)
コピー元のファイルパスを指定します。
ワイルドカードを使用することができます。
■ 引数2(必須)
コピー先のパスをファイル名まで含めて指定するか、コピー先のフォルダパスのいずれかを指定します。
なお、フォルダパスを指定する場合は、その場合は最後に「\」を付けてください。
また、ワイルドカードは使用できません。

[戻り値]

[備考]
移動先が読み取り専用になっている場合など、書き込みできない状態になっている場合には、このメソッドはエラーとなります。
移動に成功すると、移動元のファイルは削除されます。
また、移動と同時に元ファイル名を変更することもできます。

(例)
'「D:\Temp」にあるファイルを移動します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
oFSO.MoveFile "D:\Temp\File1.txt","D:\Data\"
Set oFSO = Nothing


MoveFolderメソッド
フォルダを移動します。
書式 "FileSystemObjectオブジェクト".MoveFolder(引数1,引数2)
■ 引数1(必須)
コピー元のフォルダパスを指定します。
ワイルドカードを使用することができます。
■ 引数2(必須)
コピー先のパスをフォルダ名まで含めて指定するか、コピー先の親フォルダパスのいずれかを指定します。
なお、親フォルダパスを指定する場合は、その場合は最後に「\」を付けてください。
また、ワイルドカードは使用できません。

[戻り値]

[備考]
移動先が読み取り専用になっている場合など、書き込みできない状態になっている場合には、このメソッドはエラーとなります。
移動に成功すると、移動元のフォルダは削除されます。
また、移動と同時に元フォルダ名を変更することもできます。

(例)
'「D:\Temp」にあるフォルダを移動します。
Dim oFSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
oFSO.MoveFolder "D:\Temp\Folder1","D:\Data\"
Set oFSO = Nothing


OpenAsTextStreamメソッド
テキストファイルを読み取りまたは書き込み用に開きます。
書式 "Fileオブジェクト".OpenAsTextStream(引数1,引数2)
■ 引数1
入出力モードを表す値を以下から指定します。
定数 説明
ForReading 1 読み取り専用で開きます(既定値)。
ForWriting 2 上書き書き込み専用で開きます。既存ファイルがあれば上書きします。
ForAppending 8 追加書き込み専用で開きます。既存ファイルがあれば最後に追加します。
■ 引数2
ファイルのオープン形式を表す値を以下から指定します。
定数 説明
TristateUseDefault -2 システムのデフォルトでファイルを開きます。
TristateTrue -1 Unicode形式でファイルを開きます。
TristateFalse 0 ASCII形式でファイルを開きます(既定値)。

[戻り値]
TextStreamオブジェクト

[備考]
引数1、引数2に定数文字列を指定してエラーになる場合は、値を直接指定してください。

(例)
'「D:\Temp\File1.txt」に書き込みます。
Dim oFSO, oFile, oStream
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFile = oFSO.GetFile("D:\Temp\File1.txt")
Set oStream = oFile.OpenAsTextStream(2, 0)
oStream.Write("テストです")
oStream.Close
Set oFile = Nothing
Set oStream = Nothing
Set oFSO = Nothing


OpenTextFileメソッド
テキストファイルを読み取りまたは書き込み用に開きます。
書式 "FileSystemObjectオブジェクト".OpenTextFile(引数1,引数2,引数3,引数4)
■ 引数1(必須)
ファイルパスを指定します。
■ 引数2
入出力モードを表す値を以下から指定します。
定数 説明
ForReading 1 読み取り専用で開きます(既定値)。
ForWriting 2 上書き書き込み専用で開きます。既存ファイルがあれば上書きします。
ForAppending 8 追加書き込み専用で開きます。既存ファイルがあれば最後に追加します。
■ 引数3
引数1で指定したファイルが存在しなかった場合に新しくファイルを作成するかどうかを指定します。
True を指定すると、新しくファイルを作成します。
False を指定すると、新しくファイルは作成されません。
未指定の場合は、False となります。
■ 引数4
ファイルのオープン形式を表す値を以下から指定します。
定数 説明
TristateUseDefault -2 システムのデフォルトでファイルを開きます。
TristateTrue -1 Unicode形式でファイルを開きます。
TristateFalse 0 ASCII形式でファイルを開きます(既定値)。

[戻り値]
TextStreamオブジェクト

[備考]
引数2、引数4に定数文字列を指定してエラーになる場合は、値を直接指定してください。

(例)
'「D:\Temp\File1.txt」に書き込みます。
Dim oFSO, oFile
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFile = oFSO.OpenTextFile("D:\Temp\File1.txt", 2, True)
oFile.WriteLine("テストです")
oFile.Close
Set oFile = Nothing
Set oFSO = Nothing


Readメソッド
TextStreamオブジェクトから文字を読み込みます。
書式 "TextStreamオブジェクト".Read(引数1)
■ 引数1(必須)
読み込み文字数を指定します。

[戻り値]
読み込んだ文字列

(例)
'「D:\Temp\File1.txt」の内容を読み込みます。
Dim oFSO, oStream
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oStream = oFSO.OpenTextFile("D:\Temp\File1.txt", 1, False, 0)
WScript.Echo oStream.Read(4)
oStream.Close
Set oStream = Nothing
Set oFSO = Nothing


ReadAllメソッド
TextStreamオブジェクトからファイルの内容をすべて読み込みます。
書式 "TextStreamオブジェクト".ReadAll

[戻り値]
読み込んだ文字列

(例)
'「D:\Temp\File1.txt」の内容を読み込みます。
Dim oFSO, oStream
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oStream = oFSO.OpenTextFile("D:\Temp\File1.txt", 1, False, 0)
WScript.Echo oStream.ReadAll
oStream.Close
Set oStream = Nothing
Set oFSO = Nothing


ReadLineメソッド
TextStreamオブジェクトからファイルの内容を行単位で読み込みます。
書式 "TextStreamオブジェクト".ReadLine

[戻り値]
読み込んだ文字列

(例)
'「D:\Temp\File1.txt」の内容を読み込みます。
Dim oFSO, oStream
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oStream = oFSO.OpenTextFile("D:\Temp\File1.txt", 1, False, 0)
WScript.Echo oStream.ReadLine
oStream.Close
Set oStream = Nothing
Set oFSO = Nothing


Skipメソッド
TextStreamオブジェクトから読み込むときにスキップします。
書式 "TextStreamオブジェクト".Skip(引数1)
■ 引数1(必須)
スキップする文字数を指定します。

[戻り値]

(例)
'「D:\Temp\File1.txt」の内容を読み込みます。
Dim oFSO, oStream
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oStream = oFSO.OpenTextFile("D:\Temp\File1.txt", 1, False, 0)
oStream.Skip(10)
WScript.Echo oStream.ReadLine
oStream.Close
Set oStream = Nothing
Set oFSO = Nothing


SkipLineメソッド
TextStreamオブジェクトから読み込むときに行単位でスキップします。
書式 "TextStreamオブジェクト".SkipLine

[戻り値]

(例)
'「D:\Temp\File1.txt」の内容を読み込みます。
Dim oFSO, oStream
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oStream = oFSO.OpenTextFile("D:\Temp\File1.txt", 1, False, 0)
oStream.SkipLine
WScript.Echo oStream.ReadLine
oStream.Close
Set oStream = Nothing
Set oFSO = Nothing


Writeメソッド
TextStreamオブジェクトへ文字を書き込みます。
書式 "TextStreamオブジェクト".Write(引数1)
■ 引数1(必須)
書き込む文字列を指定します。

[戻り値]

[備考]
改行コードなどは書き込まれません。

(例)
'「D:\Temp\File1.txt」に書き込みます。
Dim oFSO, oStream
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oStream = oFSO.OpenTextFile("D:\Temp\File1.txt", 2, True, 0)
oStream.Write("テストです")
oStream.Close
Set oStream = Nothing
Set oFSO = Nothing


WriteBlankLinesメソッド
TextStreamオブジェクトへ改行文字を書き込みます。
書式 "TextStreamオブジェクト".WriteBlankLines(引数1)
■ 引数1(必須)
書き込む改行文字の個数を指定します。

[戻り値]

[備考]
空行を書き込む場合に使用します。
WriteLine("")と等価です。

(例)
'「D:\Temp\File1.txt」に書き込みます。
Dim oFSO, oStream
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oStream = oFSO.OpenTextFile("D:\Temp\File1.txt", 2, True, 0)
oStream.WriteBlankLines(10)
oStream.Write("テストです")
oStream.Close
Set oStream = Nothing
Set oFSO = Nothing


WriteLineメソッド
TextStreamオブジェクトへ行単位で文字を書き込みます。
書式 "TextStreamオブジェクト".WriteLine(引数1)
■ 引数1
書き込む文字列を指定します。
未指定の場合は、空行が書き込まれます。

[戻り値]

[備考]
改行コードが自動的に追加されて書き込まれます。

(例)
'「D:\Temp\File1.txt」に書き込みます。
Dim oFSO, oStream
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oStream = oFSO.OpenTextFile("D:\Temp\File1.txt", 2, True, 0)
oStream.WriteLine("テストです")
oStream.Close
Set oStream = Nothing
Set oFSO = Nothing